Private Sub EnumAll()
   Dim lo_CommandBar As CommandBar
   Dim lo_Control As CommandBarControl
   Dim i As Long
   
   ' Enumerate top-level commandbars and their controls
   For Each lo_CommandBar In Me.CommandBars1
      Debug.Print lo_CommandBar.Title
      
      ' Enumerate this commandbar's controls
      ' EnumControls is a recursive function that will also enumerate the child controls controls,
      ' and the child controls of that's child's controls, etc....
      EnumControls lo_CommandBar
   Next lo_CommandBar

   Exit Sub
End Sub


Private Sub EnumControls(po_CommandBar As XtremeCommandBars.CommandBar, Optional ByVal p_IndentLevel As Long = 1)
   ' p_IndentLevel is used for printing to the debug window, and not needed in production code
   '               if you don't need to display the control hierarchy in a formatted/indented manner
   
   Dim lo_Control As XtremeCommandBars.CommandBarControl
   
   For Each lo_Control In po_CommandBar.Controls
      ' Print the control name at an indentation level that represents it's position in the controls tree
      Debug.Print String$(p_IndentLevel, vbTab); lo_Control.Caption
      
      ' Check to see if this control has a CommandBar child, if so it could have child controls
      ' that need enumerating
      
      ' Don't test for CommandBar in a CommandBarControlCustom object, because it will raise an error
      ' There may be other CommandBar control types that raise errors, you will have to test for this
      If Not (TypeOf lo_Control Is XtremeCommandBars.CommandBarControlCustom) Then
         ' This is not a CommandBarControlCustom object, so let's see if it has a CommandBar
         
         If Not (lo_Control.CommandBar Is Nothing) Then
            ' This control has a CommandBar, so recursively call this function to enumerate it's controls
            
            EnumControls lo_Control.CommandBar, p_IndentLevel + 1
         End If
      End If
   Next lo_Control
End Sub