Codejock Developer Community : Ribbon Control and Progress OpenEdge 10.1A

Ribbon Control and Progress OpenEdge 10.1A : Hi Arie, thanks for your help. Do...

Fri, 27 Feb 2009 12:06:22 +0000

Author: NormenT
Subject: 12708
Posted: 27 February 2009 at 12:06pm

Hi Arie,

thanks for your help.

Do you have a skype or messenger Account where i can contact you ? (i hope it is allowed to ask for)

I git some little very progress - specific Question maybe you can help ?

(Skype: Normen_T)

KdRgds and a nice Weekend

Normen

Ribbon Control and Progress OpenEdge 10.1A : I see the above code is not working...

Fri, 27 Feb 2009 03:12:05 +0000

Author: adwild2
Subject: 12708
Posted: 27 February 2009 at 3:12am

I see the above code is not working with a statusbar. This is because progress tries to resize the progress window to the size of the windows window. You have to overrule this in the resize event of the commandbars.

First an updated version of the code i wrote you first. This will correctly set the statusbar.

DEFINE VARIABLE   chPane AS COM-HANDLE NO-UNDO.
DEFINE VARIABLE   ig_Tmp AS INTEGER    NO-UNDO.
DEFINE VARIABLE   cg_Tmp AS CHARACTER NO-UNDO.
DEFINE VARIABLE   lg_Tmp AS LOGICAL    NO-UNDO.
DEFINE VARIABLE   i_hWnd AS INTEGER    NO-UNDO.
DEFINE VARIABLE   hFrame AS HANDLE     NO-UNDO.

ASSIGN hFrame = FRAME default-frame:HANDLE.
CREATE CONTROL-FRAME ocx_Toolbar
ASSIGN      FRAME        = hFrame
            ROW          = 1
            COLUMN       = 1
            HEIGHT       = 1
            WIDTH        = 1
            HIDDEN       = TRUE
            SENSITIVE    = TRUE.
ASSIGN ocx_Toolbar:NAME = "ocx_Toolbar":U
       cg_Tmp           = SEARCH( "ocx_toolbar.wrx":U )
       chocx_Toolbar    = ocx_Toolbar:COM-HANDLE
       lg_Tmp           = chocx_Toolbar:LoadControls(cg_Tmp,"ocx_CommandBars":U)
       ch_TBar          = chocx_Toolbar:CommandBars.

RUN GetParent( c-win:HWND, OUTPUT i_hWnd ). /* Get Windows-window */
RUN SetWindowPos( c-win:HWND, 0, 0, 142, 0, 0, {&SWP_NOSIZE} + {&SWP_NOZORDER}, OUTPUT ig_Tmp).
ch_TBar:AttachToWindow( i_hWnd ).

/* Create ribbonbar */
ASSIGN RibbonBar                 = ch_TBar:AddRibbonBar("RibbonBar")
       chpane                    = RibbonBar:AddSystemButton()
       RibbonBar:ShowQuickAccess = FALSE.

ch_TBar:LoadDesignerBars("test_form.xcb" ).

/* Set statusbar */
ASSIGN chStatusbar                      = ch_TBar:StatusBar
       chStatusbar:Visible              = TRUE
       chpane                           = chStatusBar:AddPane(1)
       chpane:TEXT                      = "Hello world":U.

chStatusbar:SetPaneStyle( 1, 134217728). /* Stretchable */
chStatusbar:AddPane( 59137 ). /* CAPS */
chStatusbar:AddPane( 59138 ). /* NUM */

/* Enable theme */
RibbonBar:EnableFrameTheme().

Now you have to add a procedure for the commanbars resize event:

 
PROCEDURE ocx_Toolbar.CommandBars.Resize :
DEFINE VARIABLE   i_Tmp AS INTEGER    NO-UNDO.
/* 
142 = height of ribbon
22  = height of statusbar
*/
RUN SetWindowPos( c-win:HWND, 0, 0, 0, c-win:WIDTH-PIXELS, c-win:HEIGHT-PIXELS - 142 - 22, {&SWP_NOMOVE} + {&SWP_NOZORDER}, OUTPUT i_Tmp).
 
END PROCEDURE.

Good luck.

Grtz Arie

Ribbon Control and Progress OpenEdge 10.1A : Hi, maybe i am to inexperienced....

Thu, 26 Feb 2009 10:28:32 +0000

Author: NormenT
Subject: 12708
Posted: 26 February 2009 at 10:28am

Hi,

maybe i am to inexperienced. Everything works fine (loadDesignBars works fine ?!) but the Statusbar is not working.

Can you send me a example code for this ? (resize the window doesn't work)

KdRgds.

Normen

Ribbon Control and Progress OpenEdge 10.1A : Changed your code a bit (the procedure...

Thu, 26 Feb 2009 04:31:08 +0000

Author: adwild2
Subject: 12708
Posted: 26 February 2009 at 4:31am

Changed your code a bit (the procedure "programminit"), and now it works for me. The ribbonbar is now created AFTER it is attached to the window. I disabled the xcb file from the commandbars designer because for some reason it removes the minimize, maximize and close buttons on the ribbon. I you want to use a status bar you also should decrease the height of the progress window. In the code there is a comment which describes this. If this code doesn't work for you there is probably something wrong with your .wrx file.

ASSIGN hFrame = FRAME default-frame:HANDLE.
CREATE CONTROL-FRAME ocx_Toolbar
ASSIGN      FRAME        = hFrame
             ROW          = 1
             COLUMN       = 1
             HEIGHT       = 1
             WIDTH        = 1
             HIDDEN       = TRUE
             SENSITIVE    = TRUE.
ASSIGN ocx_Toolbar:NAME = "ocx_Toolbar":U
       cg_Tmp           = SEARCH( "ocx_toolbar.wrx":U )
       chocx_Toolbar    = ocx_Toolbar:COM-HANDLE
       lg_Tmp           = chocx_Toolbar:LoadControls(cg_Tmp,"ocx_CommandBars":U)
       ch_TBar          = chocx_Toolbar:CommandBars.

RUN GetParent( c-win:HWND, OUTPUT i_hWnd ). /* Get Windows-window */
RUN SetWindowPos( c-win:HWND, 0, 0, 142, 0, 0, {&SWP_NOSIZE} + {&SWP_NOZORDER}, OUTPUT ig_Tmp).
/*
To make the statusbar visible you also have to resize the Progress window.
Then you should remove {&SWP_NOSIZE} and give a width and height in the
5th and 6th argument of SetWindowPos.
*/
ch_TBar:AttachToWindow( i_hWnd ).

ASSIGN RibbonBar = ch_TBar:AddRibbonBar("RibbonBar")
chpane = RibbonBar:AddSystemButton().

/* ch_TBar:LoadDesignerBars("test_form.xcb" ). /* if enabled it removes the windows buttons (?) */ */
ASSIGN RibbonBar:ShowQuickAccess = FALSE.
chStatusbar = ch_TBar:StatusBar.
chpane = chStatusBar:AddPane(0).

RibbonBar:EnableFrameTheme().

Ribbon Control and Progress OpenEdge 10.1A : I have already tried to increase...

Thu, 26 Feb 2009 04:04:05 +0000

Author: NormenT
Subject: 12708
Posted: 26 February 2009 at 4:04am

I have already tried to increase the size of the form, but it has no result.

(i added a screen, where you can see the results)

Ribbon Control and Progress OpenEdge 10.1A : Hi, Try to increase size of form....

Thu, 26 Feb 2009 03:56:42 +0000

Author: Oleg
Subject: 12708
Posted: 26 February 2009 at 3:56am

Hi,

Try to increase size of form.

Ribbon Control and Progress OpenEdge 10.1A : Hi rdhaan, everything is fine...

Thu, 26 Feb 2009 03:06:32 +0000

Author: NormenT
Subject: 12708
Posted: 26 February 2009 at 3:06am

Hi rdhaan,

everything is fine - but, the ribbon is not visible...uploads/20090226_030353_sample.zip

I attached a small sample - where you can see what i mean. (hope so)

The Main code is in the Proecedure programminit.

Or do you have a working small exaple ? (it should contain the LoadDesignerBars method)

Regars

Normen

Ribbon Control and Progress OpenEdge 10.1A : Normen, We use the CommandBars,...

Wed, 25 Feb 2009 09:14:55 +0000

Author: rdhaan
Subject: 12708
Posted: 25 February 2009 at 9:14am

Normen,

We use the CommandBars, not the CommandBarsFrame.

With a CONTROL-FRAME of 1 by 1 pixels and then using the AttachToWindow function is docks to the Windows window.

This works for the RibbonBar and also the CommandBar used as a Toolbar (wit then lowering the Progress windows 26 pixels).

Even when using the statusbar, is still works.

The only weird thing we had was that the Close and Maximize buttons didn't work with the SkinFrameWork

(before we docked the Toolbars to the 'Progress' window).

But after moving it to the Windows window the buttons work.

      CREATE CONTROL-FRAME ocx_Toolbar
      ASSIGN FRAME        = h_Frame
             ROW          = 1
             COLUMN       = 1
             HEIGHT       = 1
             WIDTH        = 1
             HIDDEN       = TRUE
             SENSITIVE    = TRUE.

ASSIGN ocx_Toolbar:NAME = "ocx_Toolbar":U.

   ASSIGN cg_Tmp = SEARCH( "s-tbar10.wrx":U ).
   IF cg_Tmp = ? THEN
      RETURN "ERROR":U.

   ASSIGN chocx_Toolbar = ocx_Toolbar:COM-HANDLE
          lg_Tmp        = chocx_Toolbar:LoadControls(cg_Tmp,"ocx_CommandBars":U)
          NO-ERROR.

ASSIGN ch_TBar = chocx_Toolbar:CommandBars NO-ERROR.

   IF l_Ribbon THEN
      RUN SetWindowPos( h_Window:HWND, 0, 0, 142, 0, 0, {&SWP_NOSIZE} + {&SWP_NOZORDER}, OUTPUT ig_Tmp).
   OR
      RUN SetWindowPos( h_Window:HWND, 0, 0, 26, 0, 0, {&SWP_NOSIZE} + {&SWP_NOZORDER}, OUTPUT ig_Tmp).

ch_TBar:AttachToWindow( i_hWnd ).

This is all in Progress 10.2A (but in 10.1A it should work as well).

Ribbon Control and Progress OpenEdge 10.1A : That doesn't work for me...

Sat, 21 Feb 2009 05:40:55 +0000

Author: NormenT
Subject: 12708
Posted: 21 February 2009 at 5:40am

That doesn't work for me (OpenEdge 10.1A?) with 10.1A i have to youse the CommandBarsFrame control not the CommandBars contrrol. I tried everything but only recieve a "white stripe". Does anybody get things going with the CommandBars control not withe the CommandBarsFrame control ? (I think there might bei a difference )

Normen

Ribbon Control and Progress OpenEdge 10.1A : I managed to add the Ribbonbar...

Wed, 18 Feb 2009 03:22:20 +0000

Author: adwild2
Subject: 12708
Posted: 18 February 2009 at 3:22am

I managed to add the Ribbonbar to a Progress window. I do this by attaching the Ribbon to the Windows-window and moving the Progress-window 142 pixels down using the SetWindowPos API. Here an example, I hope this will fix it for you too :

/* SetWindowPos() Constans */
&GLOBAL-DEFINE SWP_NOSIZE     1
&GLOBAL-DEFINE SWP_NOMOVE     2
&GLOBAL-DEFINE SWP_NOZORDER   4
   
PROCEDURE AddRibbonBar :
DEFINE       VARIABLE  i_hWnd             AS INTEGER      NO-UNDO.
   RUN GetParent( h_Window:HWND, OUTPUT i_hWnd ). /* Get Windows-window */
  /* Move Progress-window 142 pixels down (= height of Ribbonbar) */
   RUN SetWindowPos( h_Window:HWND, 0, 0, 142, 0, 0, {&SWP_NOSIZE} + {&SWP_NOZORDER}, OUTPUT ig_Tmp).
   
   ch_CommandBars:AttachToWindow( i_hWnd ).
   ch_RibbonBar:EnableFrameTheme().
   
END PROCEDURE.
 
PROCEDURE GetParent EXTERNAL "user32.dll" :
   DEFINE INPUT   PARAMETER ch_Window AS LONG.
   DEFINE RETURN  PARAMETER ch_Parent AS LONG.
END PROCEDURE.

PROCEDURE SetWindowPos EXTERNAL "user32.dll" :
   DEFINE INPUT  PARAMETER hwnd            AS LONG.
   DEFINE INPUT  PARAMETER hwndInsertAfter AS LONG.
   DEFINE INPUT  PARAMETER x               AS LONG.
   DEFINE INPUT  PARAMETER y               AS LONG.
   DEFINE INPUT  PARAMETER cx              AS LONG.
   DEFINE INPUT  PARAMETER cy              AS LONG.
   DEFINE INPUT  PARAMETER fuFlags         AS LONG.
   DEFINE RETURN PARAMETER ReturnValue     AS LONG.
END PROCEDURE.