Option Explicit

Private Const ES_WANTRETURN = &H1000
Private Const GWL_STYLE = (-16)
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long

Private Sub Form_Load()
   Dim l_Style As Long
   
   ' Get current FlatEdit style
   l_Style = GetWindowLong(Me.FlatEdit1.hwnd, GWL_STYLE)
   ' Ensure ES_WANTRETURN style flag is set
   SetWindowLong Me.FlatEdit1.hwnd, GWL_STYLE, l_Style Or ES_WANTRETURN
   
   ' Test to see if ES_WANTRETURN style was set properly
   l_Style = GetWindowLong(Me.FlatEdit1.hwnd, GWL_STYLE)
   Debug.Print l_Style And ES_WANTRETURN    ' Should print 4096 if set properly
End Sub

Private Sub PushButton1_Click()
   ' Shouldn't fire when user hits Enter while FlatEdit1 has focus
   ' Even when Default property = True
   MsgBox "A"
End Sub

Private Sub HoldDefaultControl(ByVal pHold As Boolean)
   '---------------------------------------------------------------------------------------
   ' Procedure  : HoldDefaultControl
   ' Purpose    : To set/unset the default property of another control on the parent of
   '              this usercontrol
   ' Parameters : pHold - TRUE (hold a reference to the current default control and
   '                            set its Default property to FALSE)
   '                      FALSE (set the Default property of the held reference to the
   '                             former default control to TRUE)
   '---------------------------------------------------------------------------------------
   
   Static sobjDefaultControl As Control
   Dim objCtrl As Control
   Dim blnFoundDefault As Boolean
   
   ' Remove default control from parent if it exists so
   ' user can hit enter in multiline textbox
   If pHold Then
      If sobjDefaultControl Is Nothing Then
      
         ' Loop through the controls on the parent form until we find the default control
         For Each objCtrl In Me.Controls
      
            ' Trap errors in case this control doesn't support default property
            On Error Resume Next
            blnFoundDefault = objCtrl.Default
            On Error GoTo 0
            
            If blnFoundDefault Then
               ' We have found the default control
               Set sobjDefaultControl = objCtrl ' Store a reference to this control
               Exit For ' Short circuit the loop since we found what we were looking for
            End If
         Next objCtrl
      End If
   End If
   
   If Not sobjDefaultControl Is Nothing Then
      ' If there is/was a default control
      sobjDefaultControl.Default = Not pHold ' Set or Unset the default property as required
   End If
End Sub

Private Sub FlatEdit1_GotFocus()
   If Me.MultiLine Then
      HoldDefaultControl True
   End If
End Sub

Private Sub FlatEdit1_LostFocus()
   HoldDefaultControl False
End Sub