ComboBox - supress Popup

Oleg,

any hint on that?

This is what I want to achieve.



This is what I currently do:

In an initialization procedure, after loading Designerbars, I do some size-Optimization and set the Combo's Dropdown to a width of 1 px. and the ItemCount to 0. This does not make the dropdown not appear but it's only a few pix in size so that the user does not realize.


    loCBO = loToolbar.FindControl(5, ID_SCHEDMAIN_DATE)

    *-- resize the combo's width to the space needed for
    *-- display of current date + room for the dropdown-
    *-- arrow + some "air"
    loCBO.Width = ;
      txtWidth(dtoc(date()), this.Text1.FontName, this.Text1.FontSize, "B")*;
      fontMetric(6, this.Text1.FontName, this.Text1.FontSize, "B")+;
      + sysMetric(5) + lnWidthAdd
         
     *-- try to hide as much of the combo as possible 
     loCBO.DropdownWidth     = 1
     loCBO.DropDownItemCount = 0


I then listen to the ControlNotify-event and show the calendar as soon as the user clicks on the down-arrow. The actual ShowCalendar() procedure is separated from the event by calling it via timer with a short delay. This way we can leave the event immediately, which is crucial to avoid "letters to Bill" as I call them (a GPF is almost a sure thing when an error occurs within VFP-Code while still being in some kind of ActiveX-event). A delay of 20ms or even less is safe enough and almost not to realize,

PROCEDURE ControlNotify(Control as Object, Code as Long, NotifyData as variant, Handled as Variant)
    if Control.ID = ID_SCHEDMAIN_DATE 
        if Code=7 && Dropdownarrow clicked and popup is about to open
            *-- "handled" is coming in via reference.
            *-- setting it to .T. should tell the toolbar
            *-- "I'll take care of it. Unfortunately it
            *-- does not seem to care. But we're good
            *-- good guys and do behave.
            Handled = .t.
           
            *-- this causes an immediate GPF:           
            *oForm = Create("FORM")
            *oForm.halfHeightcaption = .T.
            *oForm.Show
            *--> letter to Bill

            *-- ... so call the ShowCalender via timer and
            *-- let the event return immediately
            thisform.tmrAction.doCommand("thisform.ShowCalendar("+ trans(ID_SCHEDMAIN_DATE) +")")
           
        endif
    endif
ENDPROC

ShowCalendar opens and positions the form below the control

PROCEDURE ShowCalendar(tnControlID as integer) as boolean
tnControlID = iif(vartype(tnControlID) = "N", tnItemID, 1101)

public oCal
local  a,b,c,d,a1,b1,c1,d1, loTB, loCBO, loCB

store 0 to a,b,c,d, a1,b1,c1,d1

loTB    = this.TB
loCBO   = this.TB.FindControl(5, tnControlID)

if ! isNull(loCBO)
    && !!!! More generic - Test only !!!
    loCB = loTB.ActiveMenubar.Commandbars(3)

    *-- get rectangles for control and commandbar
    loCB.GetWindowRect(@a,@b,@c,@d)
    loCBO.GetRect(@a1,@b1,@c1,@d1)

    *-- frmDatePick is a class that releases itself
    *-- on lostfocus and binds itself to a target
    *-- it reports to in case a positive date-selection
    *-- is made
    oCal = newObject("frmDatePick", "SCHED_FORMS", "", ThisForm.txtDatum)

    *-- move the form below the date-combo, align with the
    *-- right border
    oCal.Move(;
        a+c1-oCal.Width-2-_screen.left,;
        b-_screen.Top + d1+3)

    oCal.Show
endif  && ! isNull(...)

ENDPROC

This works pretty well, though not the ideal solution. I'd really like to get rid of the combo's popup although the trick is almost perfect.  Any recommendations gladly welcome.

Frank.

oleg wrote:   This code works for Visual Basic:   Private Declare Function DestroyWindow Lib "user32" (ByVal hwnd As Long) As Long Private Sub CommandBars_TrackingModeChanged(ByVal CommandBar As XtremeCommandBars.ICommandBar, ByVal Mode As Boolean)     If (CommandBar.BarID = 100) Then             DestroyWindow CommandBar.hwnd     End If End Sub ....

BANG - this directly sends VFP to hell. Same when I try to do it from within the ControlNotify.

However,  the tip pointed into the right direction. Destroying the window only once seems to be enough, and when I do that directly after initializing the toolbar all further calls report a window handle of "0" and no popup appears.

So the working code now looks like this:

    loCBO = loToolbar.FindControl(5, ID_SCHEDMAIN_DATE)

    *-- resize the combo's width to the space needed for
    *-- display of current date + room for the dropdown-
    *-- arrow + some "air       
    loCBO.Width = ;
          txtWidth(dtoc(date()), this.Text1.FontName, this.Text1.FontSize, "B")*;
          fontMetric(6, this.Text1.FontName, this.Text1.FontSize, "B") + sysMetric(5) + lnWidthAdd
       
       
    *-- DD changed on 06.01.09
    *-- directly delete the combo's Commandbar-Window and
    *-- by that way prevent it from ever showing up.
 
    if loCBO.CommandBar.hWnd > 0
        declare long DestroyWindow in USER32 as CB_DestroyWindow long hWnd
        CB_DestroyWindow(loCBO.CommandBar.hWnd)
        clear Dlls CB_DestroyWindow
   endif
   ...

This seems to work like a charm and clicking the down-arrow shows the calendar as if it ever belonged there.